[#1335] Reorganized `users.mutes` as relation to UserMute entity.
parent
5cf2c7422b
commit
c31ddce51e
@ -0,0 +1,71 @@
|
||||
# Pleroma: A lightweight social networking server
|
||||
# Copyright © 2017-2019 Pleroma Authors <https://pleroma.social/>
|
||||
# SPDX-License-Identifier: AGPL-3.0-only
|
||||
|
||||
defmodule Pleroma.UserMute do
|
||||
use Ecto.Schema
|
||||
|
||||
import Ecto.Changeset
|
||||
import Ecto.Query
|
||||
|
||||
alias Pleroma.Repo
|
||||
alias Pleroma.User
|
||||
alias Pleroma.UserMute
|
||||
|
||||
schema "user_mutes" do
|
||||
belongs_to(:muter, User, type: FlakeId.Ecto.CompatType)
|
||||
belongs_to(:mutee, User, type: FlakeId.Ecto.CompatType)
|
||||
|
||||
timestamps(updated_at: false)
|
||||
end
|
||||
|
||||
def changeset(%UserMute{} = user_mute, params \\ %{}) do
|
||||
user_mute
|
||||
|> cast(params, [:muter_id, :mutee_id])
|
||||
|> validate_required([:muter_id, :mutee_id])
|
||||
|> unique_constraint(:mutee_id, name: :user_mutes_muter_id_mutee_id_index)
|
||||
|> validate_not_self_mute()
|
||||
end
|
||||
|
||||
def exists?(%User{} = muter, %User{} = mutee) do
|
||||
UserMute
|
||||
|> where(muter_id: ^muter.id, mutee_id: ^mutee.id)
|
||||
|> Repo.exists?()
|
||||
end
|
||||
|
||||
def create(%User{} = muter, %User{} = mutee) do
|
||||
%UserMute{}
|
||||
|> changeset(%{muter_id: muter.id, mutee_id: mutee.id})
|
||||
|> Repo.insert(
|
||||
on_conflict: :replace_all_except_primary_key,
|
||||
conflict_target: [:muter_id, :mutee_id]
|
||||
)
|
||||
end
|
||||
|
||||
def delete(%User{} = muter, %User{} = mutee) do
|
||||
attrs = %{muter_id: muter.id, mutee_id: mutee.id}
|
||||
|
||||
case Repo.get_by(UserMute, attrs) do
|
||||
%UserMute{} = existing_record -> Repo.delete(existing_record)
|
||||
nil -> {:ok, nil}
|
||||
end
|
||||
end
|
||||
|
||||
defp validate_not_self_mute(%Ecto.Changeset{} = changeset) do
|
||||
changeset
|
||||
|> validate_change(:mutee_id, fn _, mutee_id ->
|
||||
if mutee_id == get_field(changeset, :muter_id) do
|
||||
[mutee_id: "can't be equal to muter_id"]
|
||||
else
|
||||
[]
|
||||
end
|
||||
end)
|
||||
|> validate_change(:muter_id, fn _, muter_id ->
|
||||
if muter_id == get_field(changeset, :mutee_id) do
|
||||
[muter_id: "can't be equal to mutee_id"]
|
||||
else
|
||||
[]
|
||||
end
|
||||
end)
|
||||
end
|
||||
end
|
@ -0,0 +1,14 @@
|
||||
defmodule Pleroma.Repo.Migrations.CreateUserMutes do
|
||||
use Ecto.Migration
|
||||
|
||||
def change do
|
||||
create_if_not_exists table(:user_mutes) do
|
||||
add(:muter_id, references(:users, type: :uuid, on_delete: :delete_all))
|
||||
add(:mutee_id, references(:users, type: :uuid, on_delete: :delete_all))
|
||||
|
||||
timestamps(updated_at: false)
|
||||
end
|
||||
|
||||
create_if_not_exists(unique_index(:user_mutes, [:muter_id, :mutee_id]))
|
||||
end
|
||||
end
|
@ -0,0 +1,48 @@
|
||||
defmodule Pleroma.Repo.Migrations.DataMigrationPopulateUserMutes do
|
||||
use Ecto.Migration
|
||||
|
||||
alias Ecto.Adapters.SQL
|
||||
alias Pleroma.Repo
|
||||
|
||||
require Logger
|
||||
|
||||
def up do
|
||||
{:ok, %{rows: mute_rows}} = SQL.query(Repo, "SELECT id, mutes FROM users WHERE mutes != '{}'")
|
||||
|
||||
mutee_ap_ids =
|
||||
Enum.flat_map(
|
||||
mute_rows,
|
||||
fn [_, ap_ids] -> ap_ids end
|
||||
)
|
||||
|> Enum.uniq()
|
||||
|
||||
# Selecting ids of all mutees at once in order to reduce the number of SELECT queries
|
||||
{:ok, %{rows: mutee_ap_id_id}} =
|
||||
SQL.query(Repo, "SELECT ap_id, id FROM users WHERE ap_id = ANY($1)", [mutee_ap_ids])
|
||||
|
||||
mutee_id_by_ap_id = Enum.into(mutee_ap_id_id, %{}, fn [k, v] -> {k, v} end)
|
||||
|
||||
Enum.each(
|
||||
mute_rows,
|
||||
fn [muter_id, mutee_ap_ids] ->
|
||||
muter_uuid = Ecto.UUID.cast!(muter_id)
|
||||
|
||||
for mutee_ap_id <- mutee_ap_ids do
|
||||
mutee_id = mutee_id_by_ap_id[mutee_ap_id]
|
||||
|
||||
with {:ok, mutee_uuid} <- mutee_id && Ecto.UUID.cast(mutee_id) do
|
||||
execute(
|
||||
"INSERT INTO user_mutes(muter_id, mutee_id, inserted_at) " <>
|
||||
"VALUES('#{muter_uuid}'::uuid, '#{mutee_uuid}'::uuid, now()) " <>
|
||||
"ON CONFLICT (muter_id, mutee_id) DO NOTHING"
|
||||
)
|
||||
else
|
||||
_ -> Logger.warn("Missing reference: (#{muter_uuid}, #{mutee_id})")
|
||||
end
|
||||
end
|
||||
end
|
||||
)
|
||||
end
|
||||
|
||||
def down, do: :noop
|
||||
end
|
Loading…
Reference in new issue